PluginCat: mbmon_

#!/usr/bin/perl -w
# -*- perl -*-
# Wildcard plugin to monitor sensors.
#
# Requirements:
#       - mbmon program installed and in path
#
# Parameters supported:
#
#       config
#       autoconf
#       suggest
#
# Configurable variables
#
#       mbmon             - Override default program
#       ignore_temp<n>    - Temperature <n> will not be plotted
#       ignore_fan<n>     - Fan <n> will not be plotted
#       ignore_volt<n>    - Voltage <n> will not be plotted
#
# $Log$
# Revision 1.1  2006/03/02 09:30:00  fra519
# Modify script sensors_ for use mbmon program
#
#
#
# Magic markers:
#%# family=manual
#%# capabilities=autoconf suggest

use strict;

my $SENSORS = $ENV{'mbmon'} || 'mbmon -c1 -r';
my %config = (
               fan => {
                         regex => qr/^(F\S[^ ]*)\s*:\s+\+?(-?\d+(?:\.\d+)?)/m,
                         title => 'Fans',
                         vtitle => 'RPM',
                         graph_args => '--base 1000 -l 0'
                       },
               temp => {
                         regex => qr/^(T\S[^ ]*)\s*:\s+\+?(-?\d+(?:\.\d+)?)/m,
                         title => 'Temperatures',
                         vtitle => 'Celsius',
                         graph_args => '--base 1000 -l 0'
                       },
               volt => {
                         regex => qr/^(V\S[^ ]*)\s*:\s+\+?(-?\d+(?:\.\d+)?)/m,
                         title => 'Voltages',
                         vtitle => 'Volt',
                         graph_args => '--base 1000 --logarithmic'
                       },
             );

if ( exists $ARGV[0] and $ARGV[0] eq 'autoconf' ) {
  # Now see if "sensors" can run
  my $text = `$SENSORS`;
  if ($?) {
    if ($? == -1) {
      print "no (program $SENSORS not found)\n";
    } else {
      print "no (program $SENSORS died)\n";
    }
    exit 1;
  }

  unless ($text =~ /[:word:No]/) {
    print "no (no readings)\n";
    exit 1;
  }

  print "yes\n";
  exit 0;
}

if ($ARGV[0] and $ARGV[0] eq 'suggest') {
  my $text = `$SENSORS`;
  foreach my $func (keys %config) {
    print $func, "\n" if $text =~ $config{$func}->{regex};
  }
  exit;
}

$0 =~ /mbmon_(.+)*$/;
my $func = $1;
exit 2 unless defined $func;

if ( exists $ARGV[0] and $ARGV[0] eq 'config' ) {
  print "graph_title $config{$func}->{title}\n";
  print "graph_vtitle $config{$func}->{vtitle}\n";
  print "graph_args $config{$func}->{graph_args}\n";
  print "graph_category sensors\n";
  my $text = `$SENSORS`;
  my $sensor = 1;
  while ($text =~ /$config{$func}->{regex}/g) {
    my $label = "$1";
    print "$func$sensor.label $label\n";
    print "$func$sensor.graph no\n" if exists $ENV{"ignore_$func$sensor"};
    $sensor++;
  }
  exit 0;
}

my $text = `$SENSORS`;
my $sensor = 1;
while ($text =~ /$config{$func}->{regex}/g) {
  print "$func$sensor.value $2\n";
  $sensor++;
}

# vim:syntax=perl